root/trunk/fm_server/configure.ac

# Initialization
AC_INIT([FreeMix Server], [0.1], [alberto.botti@yoda2000.net], [fm_server])
AC_CONFIG_SRCDIR([config.h.in])
AC_CONFIG_HEADER([config.h])
AC_CONFIG_MACRO_DIR([m4])

AM_INIT_AUTOMAKE
AC_LIBTOOL_WIN32_DLL
AC_PROG_LIBTOOL
AM_GNU_GETTEXT([external])



# Checks for programs.
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET



# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])



# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_TYPE_SIZE_T
AC_C_VOLATILE



# Checks for library functions.
AC_FUNC_MALLOC
AC_TYPE_SIGNAL
AC_CHECK_FUNCS([memset strerror])
AC_CHECK_FUNCS(sched_setscheduler)
AC_CHECK_FUNCS(malloc calloc free memcpy memmove)
AC_CHECK_LIB([m],floor)
AC_CHECK_FUNCS(floor ceil fmod)
AC_C99_FUNC_LRINT
AC_C99_FUNC_LRINTF
# AC_C99_FUNC_LLRINT  Don't need this (yet?).



# Check for dependencies
PKG_CHECK_MODULES(GLIB, glib-2.0 gthread-2.0 gobject-2.0)
AC_SUBST(GLIB_LIBS)
AC_SUBST(GLIB_CFLAGS)

PKG_CHECK_MODULES(LIBXML, libxml-2.0)
AC_SUBST(LIBXML_LIBS)
AC_SUBST(LIBXML_CFLAGS)

PKG_CHECK_MODULES(GSTREAMER, gstreamer-0.10 gstreamer-base-0.10 gstreamer-plugins-base-0.10)
AC_SUBST(GSTREAMER_LIBS)
AC_SUBST(GSTREAMER_CFLAGS)

PKG_CHECK_MODULES(SAMPLERATE, samplerate)
AC_SUBST(SAMPLERATE_LIBS)
AC_SUBST(SAMPLERATE_CFLAGS)

PKG_CHECK_MODULES(RUBBERBAND, rubberband = 1.2 fftw3 samplerate)
AC_SUBST(RUBBERBAND_LIBS)
AC_SUBST(RUBBERBAND_CFLAGS)

PKG_CHECK_MODULES(RGC_SERVER, rgc_server)
AC_SUBST(RGC_SERVER_LIBS)
AC_SUBST(RGC_SERVER_CFLAGS)

PKG_CHECK_MODULES(RGC_CLIENT, rgc_client)
AC_SUBST(RGC_CLIENT_LIBS)
AC_SUBST(RGC_CLIENT_CFLAGS)


PKG_CHECK_MODULES(ALSA, alsa, got_alsa=yes, got_alsa=no)
AC_SUBST(ALSA_LIBS)
AC_SUBST(ALSA_CFLAGS)
AM_CONDITIONAL(HAVE_ALSA, test $got_alsa = yes)
if test "$got_alsa" = "yes"; then
        AC_DEFINE_UNQUOTED(HAVE_ALSA, 1, [ ALSA is available. ])
fi


PKG_CHECK_MODULES(JACK, jack, got_jack=yes, got_jack=no)
AC_SUBST(JACK_LIBS)
AC_SUBST(JACK_CFLAGS)
AM_CONDITIONAL(HAVE_JACK, test $got_jack = yes)
if test "$got_jack" = "yes"; then
        AC_DEFINE_UNQUOTED(HAVE_JACK, 1, [ JACK is available. ])
fi


PKG_CHECK_MODULES(PULSE, libpulse, got_pulse=yes, got_pulse=no)
AC_SUBST(PULSE_LIBS)
AC_SUBST(PULSE_CFLAGS)
AM_CONDITIONAL(HAVE_PULSE, test $got_pulse = yes)
if test "$got_pulse" = "yes"; then
        AC_DEFINE_UNQUOTED(HAVE_PULSE, 1, [ PulseAudio is available. ])
fi




case "x$ac_cv_c99_lrint$ac_cv_c99_lrintf" in
        xyesyes)
                ;;
        *)
                AC_MSG_WARN([[*** Missing C99 standard functions lrint() and lrintf().]])
                AC_MSG_WARN([[*** This may cause benign compiler warnings on some systems (ie Solaris).]])
                ;;
        esac


# Determine if the processor can do clipping on float to int conversions.

if test x$ac_arg_cpu_clip = "xY" ; then
        AC_C_CLIP_MODE
else
        echo "checking processor clipping capabilities... disabled"
        ac_cv_c_clip_positive=0
        ac_cv_c_clip_negative=0
        fi

AC_DEFINE_UNQUOTED(CPU_CLIPS_POSITIVE, ${ac_cv_c_clip_positive},
        [Target processor clips on positive float to int conversion.])
AC_DEFINE_UNQUOTED(CPU_CLIPS_NEGATIVE, ${ac_cv_c_clip_negative},
        [Target processor clips on negative float to int conversion.])



# Location defines

# Set PACKAGE_LOCALE_DIR in config.h.
if test "x${prefix}" = "xNONE"; then
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${ac_default_prefix}/${DATADIRNAME}/locale", [""])
else
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${prefix}/${DATADIRNAME}/locale", [""])
fi

# Set PACKAGE SOURCE DIR in config.h.
packagesrcdir=`cd $srcdir && pwd`

# Set PACKAGE PREFIX
if test "x${prefix}" = "xNONE"; then
  packageprefix=${ac_default_prefix}
else
  packageprefix=${prefix}
fi

# Set PACKAGE DATA & DOC DIR
packagedatadir=share/${PACKAGE}
packagedocdir=doc/${PACKAGE}

# Set PACKAGE DIRS in config.h.
packagepixmapsdir=${packagedatadir}/pixmaps
packagehelpdir=${packagedatadir}/help
packagemenudir=${packagedatadir}

# Subst PACKAGE_DATA_DIR.
NO_PREFIX_PACKAGE_DATA_DIR="${packagedatadir}"
AC_SUBST(NO_PREFIX_PACKAGE_DATA_DIR)
PACKAGE_DATA_DIR="${packageprefix}/${packagedatadir}"
AC_SUBST(PACKAGE_DATA_DIR)

# Subst PACKAGE_DOC_DIR.
NO_PREFIX_PACKAGE_DOC_DIR="${packagedocdir}"
AC_SUBST(NO_PREFIX_PACKAGE_DOC_DIR)
PACKAGE_DOC_DIR="${packageprefix}/${packagedocdir}"
AC_SUBST(PACKAGE_DOC_DIR)

# Subst PACKAGE_PIXMAPS_DIR.
NO_PREFIX_PACKAGE_PIXMAPS_DIR="${packagepixmapsdir}"
AC_SUBST(NO_PREFIX_PACKAGE_PIXMAPS_DIR)
PACKAGE_PIXMAPS_DIR="${packageprefix}/${packagepixmapsdir}"
AC_SUBST(PACKAGE_PIXMAPS_DIR)

# Subst PACKAGE_HELP_DIR.
NO_PREFIX_PACKAGE_HELP_DIR="${packagehelpdir}"
AC_SUBST(NO_PREFIX_PACKAGE_HELP_DIR)
PACKAGE_HELP_DIR="${packageprefix}/${packagehelpdir}"
AC_SUBST(PACKAGE_HELP_DIR)

# Subst PACKAGE_MENU_DIR.
NO_PREFIX_PACKAGE_MENU_DIR="${packagemenudir}"
AC_SUBST(NO_PREFIX_PACKAGE_MENU_DIR)
PACKAGE_MENU_DIR="${packageprefix}/${packagemenudir}"
AC_SUBST(PACKAGE_MENU_DIR)

AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${packageprefix}/${packagedatadir}", [""])
AC_DEFINE_UNQUOTED(PACKAGE_DOC_DIR, "${packageprefix}/${packagedocdir}", [""])
AC_DEFINE_UNQUOTED(PACKAGE_PIXMAPS_DIR, "${packageprefix}/${packagepixmapsdir}", [""])
AC_DEFINE_UNQUOTED(PACKAGE_HELP_DIR, "${packageprefix}/${packagehelpdir}", [""])
AC_DEFINE_UNQUOTED(PACKAGE_MENU_DIR, "${packageprefix}/${packagemenudir}", [""])
AC_DEFINE_UNQUOTED(PACKAGE_SOURCE_DIR, "${packagesrcdir}", [""])



SHAVE_INIT(.,enable)

AC_CONFIG_FILES([Makefile
                 shave
                 shave-libtool
                 po/Makefile.in
                 src/Makefile
                 src/fm_input_buffer/Makefile
                 src/fm_input_gst/Makefile
                 src/fm_effect_rubber/Makefile
                 src/fm_song_db/Makefile
                 test/Makefile])
AC_OUTPUT



# Configuration summary
echo ""
echo ""
echo "Optional components:"
if test "$got_jack" = "yes"; then
echo "        JACK output plugin:       yes"
else
echo "        JACK output plugin:       no"
fi
if test "$got_alsa" = "yes"; then
echo "        ALSA output plugin:       yes"
else
echo "        ALSA output plugin:       no"
fi
if test "$got_pulse" = "yes"; then
echo "        PulseAudio output plugin: yes"
else
echo "        PulseAudio output plugin: no"
fi
echo ""
echo "Build options:"
echo "        CFLAGS: ${CFLAGS}"
echo ""
echo "Installation options:"
echo "        fm_server will be installed to ${prefix}"
echo ""